﻿Shader "SnapshotProHDRP/Drawing"
{
    HLSLINCLUDE

    #pragma target 4.5
    #pragma only_renderers d3d11 ps4 xboxone vulkan metal switch

    #include "Packages/com.unity.render-pipelines.core/ShaderLibrary/Common.hlsl"
    #include "Packages/com.unity.render-pipelines.core/ShaderLibrary/Color.hlsl"
    #include "Packages/com.unity.render-pipelines.high-definition/Runtime/ShaderLibrary/ShaderVariables.hlsl"
    #include "Packages/com.unity.render-pipelines.high-definition/Runtime/PostProcessing/Shaders/FXAA.hlsl"
    #include "Packages/com.unity.render-pipelines.high-definition/Runtime/PostProcessing/Shaders/RTUpscale.hlsl"

    struct Attributes
    {
        uint vertexID : SV_VertexID;
        UNITY_VERTEX_INPUT_INSTANCE_ID
    };

    struct Varyings
    {
        float4 positionCS : SV_POSITION;
        float2 texcoord   : TEXCOORD0;
        UNITY_VERTEX_OUTPUT_STEREO
    };

    Varyings Vert(Attributes input)
    {
        Varyings output;
        UNITY_SETUP_INSTANCE_ID(input);
        UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(output);
        output.positionCS = GetFullScreenTriangleVertexPosition(input.vertexID);
        output.texcoord = GetFullScreenTriangleTexCoord(input.vertexID);
        return output;
    }

    // List of properties to control your post process effect
    TEXTURE2D_X(_InputTexture);
	sampler2D _DrawingTex;

	float _OverlayOffset;
	float _Strength;
	float _Tiling;
	float _Smudge;
	float _DepthThreshold;

    float4 CustomPostProcess(Varyings input) : SV_Target
    {
        UNITY_SETUP_STEREO_EYE_INDEX_POST_VERTEX(input);

		uint2 positionSS = input.texcoord * _ScreenSize.xy;

		float2 drawingUV = input.texcoord * _Tiling + _OverlayOffset;
		drawingUV.y *= _ScreenSize.y / _ScreenSize.x;
		float3 drawingCol = (tex2D(_DrawingTex, drawingUV).xyz +
			tex2D(_DrawingTex, drawingUV / 3.0f).xyz) / 2.0f;

		float2 texUV = positionSS + drawingCol * _Smudge * _ScreenSize.xy;
		float3 col = LOAD_TEXTURE2D_X(_InputTexture, texUV).xyz;

		float lum = Luminance(col);
		float3 drawing = lerp(col, drawingCol * col, (1.0f - lum) * _Strength);

		float depth = LOAD_TEXTURE2D_X(_CameraDepthTexture, positionSS).r;
		depth = Linear01Depth(depth, _ZBufferParams);

		return float4(depth < _DepthThreshold ? drawing : col, 1.0f);
    }

    ENDHLSL

    SubShader
    {
        Pass
        {
            Name "Drawing"

            ZWrite Off
            ZTest Always
            Blend Off
            Cull Off

            HLSLPROGRAM
                #pragma fragment CustomPostProcess
                #pragma vertex Vert
            ENDHLSL
        }
    }
    Fallback Off
}
